home *** CD-ROM | disk | FTP | other *** search
/ Libris Britannia 4 / science library(b).zip / science library(b) / HAM_RAD / PROPAGAT / 1004A.ZIP / EMELINK2.BAS < prev    next >
BASIC Source File  |  1986-05-23  |  2KB  |  75 lines
  1. 10 REM OVERALL PERFORMANCE OF AN EME STATION
  2. 20 REM BY G3WDG
  3. 30 REM HAM RADIO TODAY, MAY 84, P.15
  4. 40 CLS:KEY OFF:SCREEN 0
  5. 100 REM EME LINK BUDGET PROGRAM
  6. 110 REM DATA INPUT DRIVER
  7. 120 GOSUB 210
  8. 130 GOSUB 230
  9. 140 GOSUB 250
  10. 150 GOSUB 270
  11. 160 GOSUB 290
  12. 170 GOSUB 310
  13. 180 GOSUB 330
  14. 190 GOTO 360
  15. 200 REM INITIAL DATA INPUT
  16. 210 INPUT"OVERALL RX NOISE FIGURE";N
  17. 220 RETURN
  18. 230 INPUT"RX BANDWIDTH (HZ)";B
  19. 240 RETURN
  20. 250 INPUT"FREQUENCY (MHZ)";F
  21. 260 RETURN
  22. 270 INPUT"ANTENNA 1 PARAMETERS: DIA (FT.) OR GAIN (DB-PREFIX WITH DOT, E.G. .22)";D1
  23. 280 RETURN
  24. 290 INPUT"ANTENNA 2 PARAMETERS: DIA (FT.) OR GAIN (DB)";D2
  25. 300 RETURN
  26. 310 INPUT"TRANSMITTER POWER (W)";P
  27. 320 RETURN
  28. 330 INPUT"TX FEEDER LOSS (DB)";FL
  29. 340 RETURN
  30. 350 RETURN
  31. 360 REM ANTENNA CALCULATIONS
  32. 370 D=D1:GOSUB 410
  33. 380 G1=G:A1$=D$:A1=A
  34. 390 D=D2:GOSUB 410
  35. 400 G2=G:A2$=D$:A2=A:GOTO 450
  36. 410 IF D<1 THEN GOTO 430
  37. 420 D$="FT.":G=(4.3422*LOG(5.094*D*D*F*F))-60:A=D:GOTO 440
  38. 430 D$="DB":G=100*D:A=G
  39. 440 RETURN
  40. 450 REM CONVERSION OF NOISE FIGURE TO NOISE TEMPERATURE
  41. 460 NN=290*(EXP(.2303*N)-1)
  42. 470 REM CALCULATION OF RECEIVER NOISE POWER
  43. 480 RS=-228.6+(4.3422*LOG(NN+50))+4.3422*LOG(B)
  44. 490 REM CALCULATION OF PATH LOSS
  45. 500 PL=-271+8.6844*(LOG(1296/F))
  46. 510 REM CALCULATION OF SIGNAL TO NOISE RATIO
  47. 520 SN=G1+G2+(4.3422*LOG(P))+PL-RS-FL
  48. 530 REM DATA OUTPUT SECTION
  49. 540 PRINT:PRINT:PRINT"CODE PARAMETER       CURRENT VALUE"
  50. 550 PRINT
  51. 560 PRINT"1     OVERALL RX NF";N;"DB"
  52. 570 PRINT"2     BANDWIDTH";B;"HZ"
  53. 580 PRINT"3     FREQUENCY";F;"MHZ"
  54. 590 PRINT"4     ANTENNA 1";A1;A1$
  55. 600 PRINT"5     ANTENNA 2";A2;A2$
  56. 610 PRINT"6     TX POWER";P;"W"
  57. 620 PRINT"7     TX FEEDER LOSS";FL;"DB"
  58. 630 SN=INT(SN*100)/100
  59. 640 PRINT
  60. 650 PRINT"SIGNAL TO NOISE RATIO = ";SN;"DB"
  61. 660 REM RE-RUN MENU
  62. 670 INPUT"NEW PARAM CODE, RE-RUN (R) OR QUIT (Q)";A$
  63. 680 REM DATA INPUT FOR NEW PARAMETER
  64. 690 IF A$="Q" THEN GOTO 790
  65. 700 IF A$="R" THEN GOTO 120
  66. 710 IF A$="1" THEN GOSUB 210
  67. 720 IF A$="2" THEN GOSUB 230
  68. 730 IF A$="3" THEN GOSUB 250
  69. 740 IF A$="4" THEN GOSUB 270
  70. 750 IF A$="5" THEN GOSUB 290
  71. 760 IF A$="6" THEN GOSUB 310
  72. 770 IF A$="7" THEN GOSUB 330
  73. 780 GOTO 360
  74. 790 END
  75.