home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Libris Britannia 4
/
science library(b).zip
/
science library(b)
/
HAM_RAD
/
PROPAGAT
/
1004A.ZIP
/
EMELINK2.BAS
< prev
next >
Wrap
BASIC Source File
|
1986-05-23
|
2KB
|
75 lines
10 REM OVERALL PERFORMANCE OF AN EME STATION
20 REM BY G3WDG
30 REM HAM RADIO TODAY, MAY 84, P.15
40 CLS:KEY OFF:SCREEN 0
100 REM EME LINK BUDGET PROGRAM
110 REM DATA INPUT DRIVER
120 GOSUB 210
130 GOSUB 230
140 GOSUB 250
150 GOSUB 270
160 GOSUB 290
170 GOSUB 310
180 GOSUB 330
190 GOTO 360
200 REM INITIAL DATA INPUT
210 INPUT"OVERALL RX NOISE FIGURE";N
220 RETURN
230 INPUT"RX BANDWIDTH (HZ)";B
240 RETURN
250 INPUT"FREQUENCY (MHZ)";F
260 RETURN
270 INPUT"ANTENNA 1 PARAMETERS: DIA (FT.) OR GAIN (DB-PREFIX WITH DOT, E.G. .22)";D1
280 RETURN
290 INPUT"ANTENNA 2 PARAMETERS: DIA (FT.) OR GAIN (DB)";D2
300 RETURN
310 INPUT"TRANSMITTER POWER (W)";P
320 RETURN
330 INPUT"TX FEEDER LOSS (DB)";FL
340 RETURN
350 RETURN
360 REM ANTENNA CALCULATIONS
370 D=D1:GOSUB 410
380 G1=G:A1$=D$:A1=A
390 D=D2:GOSUB 410
400 G2=G:A2$=D$:A2=A:GOTO 450
410 IF D<1 THEN GOTO 430
420 D$="FT.":G=(4.3422*LOG(5.094*D*D*F*F))-60:A=D:GOTO 440
430 D$="DB":G=100*D:A=G
440 RETURN
450 REM CONVERSION OF NOISE FIGURE TO NOISE TEMPERATURE
460 NN=290*(EXP(.2303*N)-1)
470 REM CALCULATION OF RECEIVER NOISE POWER
480 RS=-228.6+(4.3422*LOG(NN+50))+4.3422*LOG(B)
490 REM CALCULATION OF PATH LOSS
500 PL=-271+8.6844*(LOG(1296/F))
510 REM CALCULATION OF SIGNAL TO NOISE RATIO
520 SN=G1+G2+(4.3422*LOG(P))+PL-RS-FL
530 REM DATA OUTPUT SECTION
540 PRINT:PRINT:PRINT"CODE PARAMETER CURRENT VALUE"
550 PRINT
560 PRINT"1 OVERALL RX NF";N;"DB"
570 PRINT"2 BANDWIDTH";B;"HZ"
580 PRINT"3 FREQUENCY";F;"MHZ"
590 PRINT"4 ANTENNA 1";A1;A1$
600 PRINT"5 ANTENNA 2";A2;A2$
610 PRINT"6 TX POWER";P;"W"
620 PRINT"7 TX FEEDER LOSS";FL;"DB"
630 SN=INT(SN*100)/100
640 PRINT
650 PRINT"SIGNAL TO NOISE RATIO = ";SN;"DB"
660 REM RE-RUN MENU
670 INPUT"NEW PARAM CODE, RE-RUN (R) OR QUIT (Q)";A$
680 REM DATA INPUT FOR NEW PARAMETER
690 IF A$="Q" THEN GOTO 790
700 IF A$="R" THEN GOTO 120
710 IF A$="1" THEN GOSUB 210
720 IF A$="2" THEN GOSUB 230
730 IF A$="3" THEN GOSUB 250
740 IF A$="4" THEN GOSUB 270
750 IF A$="5" THEN GOSUB 290
760 IF A$="6" THEN GOSUB 310
770 IF A$="7" THEN GOSUB 330
780 GOTO 360
790 END